Kawa.netブログ（川崎有亮）

rss2json.pl

#!/usr/bin/perl
# rss2json.pl
# Copyright 2006 Yusuke Kawasaki http://www.kawa.net/

# JSON または JSON::Syck のどちらかが必須。
# use JSON;
    use JSON::Syck;
    use XML::FeedPP;

# JSON出力するアイテム数と拡張要素

    my $MAX_ITEM = 10;
    my $ITEM_KEYS = [qw( media:thumbnail@url media:thumbnail@width media:thumbnail@height )];

# RSSファイル名（またはURL）と、出力するJSONファイル名

    my $file = shift @ARGV;
    my $out = shift @ARGV;
    unless ( defined $out ) {
        $out = $file;
        $out =~ s/\.[^\.]+$/.json/g;
    }

# XML::FeedPP モジュールでRSS/RDF/Atomファイルを展開する（形式問わず）

    my $feed = XML::FeedPP->new($file);
    $feed->normalize();
    $feed->limit_item( $MAX_ITEM );

# チャンネル情報を取り出す

    my $channel = {};
    $channel->{title} = $feed->title();
    $channel->{link} = $feed->link();
    $channel->{pubDate} = $feed->pubDate();

# アイテム情報を取り出す

    my $list = [];
    foreach my $item ( $feed->get_item() ) {
        my $hash = {
            title => $item->title(),
            link => $item->link(),
            pubDate => $item->pubDate(),
            author => $item->author(),
        };
        foreach my $key ( @$ITEM_KEYS ) {
            my $val = $item->get($key) or next;
            $hash->{$key} = $val;
        }
        push( @$list, $hash );
    }
    $channel->{item} = $list;

# JSON 形式に変換する

    my $tree = { rss => { channel => $channel }};
    my $text = JSON::Syck::Dump( $tree );
# my $text = objToJson( $tree );
    $text .= "\n";

# 前回の出力ファイルがあれば、内容を読み込む

    open( IN, $out ) and do {
        local $/ = undef;
        my $prev = <IN>;
        close( IN );
        if ( $prev eq $text ) {
            print STDERR "Nothing changed.\n";
            exit 0;
        }
    };

# 新しい内容で書き出す

    open( OUT, "> $out" ) or die "$! - $out\n";
    print OUT $text;
    close( OUT );

# 終了〜♪

    print STDERR "$out updated.\n";

perl ./rss2json.pl index.rss
perl ./rss2json.pl http://www.kawa.net/index.rdf hoge.json